10 POKE53280,2:POKE53281,15:POKE646,11:PRINT"[147]":GOSUB480
20 PRINTSPC(19)"NOTEPAD"
30 PRINTSPC(19)"PRINTER"
40 DIMVLIR(1,127)
50 FS$="NOTES":FORCT=0TO15:PD$=PD$+CHR$(160):NEXTCT:FS$=LEFT$(FS$+PD$,16)
60 OPEN15,8,15,"I0"
70 INPUT#15,ER$,EM$:IFER$<>"00"THENPRINTER$+" "+EM$:CLOSE15:END
80 T=18:S=1:PRINT"SEARCHING FOR NOTES"
90 OPEN2,8,2,"#"
100 PRINT#15,"U1";2;0;T;S:FC=0:FP=2:BP=5
110 PRINT#15,"B-P";2;0:GET#2,NT$,NS$:T=ASC(NT$+CHR$(0)):S=ASC(NS$+CHR$(0))
120 PRINT#15,"B-P";2;FP:GET#2,FT$:IFASC(FS$+CHR$(0))=0THEN190
130 PRINT#15,"B-P";2;BP
140 FORCT=0TO15:GET#2,BI$:FI=ASC(BI$+CHR$(0)):IFFI>96ANDFI<123THENFI=FIAND223
150 DN$=DN$+CHR$(FI)
160 NEXTCT
170 IFDN$=FS$THEN220
180 DN$=""
190 FC=FC+1:IFFC=8ANDT<>0THEN100
200 IFFC=8ANDT=0THEN510
210 FP=FP+32:BP=BP+32:GOTO120
220 PRINT"STANDBY-SCANNING NOTEPAD"
230 PRINT#15,"B-P";2;BP-2:GET#2,VT$,VS$:VT=ASC(VT$+CHR$(0)):VS=ASC(VS$+CHR$(0))
240 PRINT#15,"U1";2;0;VT;VS:PRINT#15,"B-P";2;2
250 GET#2,PT$,PS$
260 PT=ASC(PT$+CHR$(0)):PS=ASC(PS$+CHR$(0)):IFPC=0ANDPT=0THEN520
270 IFPT=0THEN310
280 VLIR(0,PC)=PT:VLIR(1,PC)=PS
290 PC=PC+1:IFPC=127THEN310
300 GOTO250
310 CLOSE2:CLOSE15
320 IFPC>1THENPRINT"THERE ARE "PC"PAGES IN THIS NOTEPAD":GOTO340
330 PRINT"THERE IS 1 PAGE IN THIS NOTEPAD"
340 PRINT"DO YOU WANT TO PRINT THE E[146]NTIRE NOTEPAD OR A S[146]INGLE PAGE;";
350 INPUT"E/S";AN$:IFAN$="E"THEN380
360 IFAN$="S"THEN420
370 GOTO340
380 FORCT=0TOPC-1
390 GOSUB530
400 NEXTCT
410 PRINTSPC(18)"DONE!":END
420 PRINT"WHICH PAGE DO YOU WANT TO PRINT 1 -";PC
430 INPUT"-> ";AN$:CT=VAL(AN$)-1:IFCT<0ORCT>PCTHENPRINT"[145][145][145][145]":GOTO420
440 GOSUB530
450 PRINT"[145][145]DO YOU WANT TO PRINT ANOTHER PAGE?     "
460 INPUT"Y/N   [157][157][157]";AN$:IFAN$="Y"THENPRINT"[145][145][145][145]":GOTO420
470 PRINTSPC(18)"DONE!":END
480 FORID=1TO63:READNI:POKE895+ID,NI:NEXTID
490 POKE53269,3:POKE2041,14:POKE53288,11:POKE53250,145:POKE53251,55
500 RETURN
510 PRINTSPC(4)"THERE ARE NO NOTES ON THIS DISK![151]":CLOSE15:END
520 PRINTSPC(3)"THERE ARE NO PAGES IN THE NOTEPAD![151]":CLOSE15:END
530 C=0:TC=0:NP$="":OPEN15,8,15:OPEN2,8,2,"#"
540 PRINT#15,"U1";2;0;VLIR(0,CT);VLIR(1,CT)
550 PRINT#15,"B-P";2;2
560 GET#2,PP$:TC=TC+1
570 PL=ASC(PP$+CHR$(0)):IFPL=0THEN620
580 IFPL>96ANDPL<123THENPL=PLAND223
590 NP$=NP$+CHR$(PL)
600 IFTC=254THEN620
610 GOTO560
620 CLOSE2:CLOSE15
630 OPEN4,4:PRINT#4,"PAGE ";CT+1:PRINT#4,NP$:PRINT#4:CLOSE4:RETURN
640 REM *-> ICON (SPRITE) DATA <-*
650 DATA255,255,255,128,000,001,131,255
660 DATA193,130,057,193,131,255,193,130
670 DATA000,065,130,000,065,130,000,065
680 DATA130,000,065,130,000,065,131,000
690 DATA065,130,128,065,131,255,193,128
700 DATA000,001,135,255,225,137,036,157
710 DATA159,255,253,159,255,253,143,255
720 DATA241,128,000,001,255,255,255,167